Exponential Lifetimes

A.I. McLeod
Department of Statistical and Actuarial Sciences,
University of Western Ontario,
e-mail: aim@uwo.ca

B. Quenneville,
Statistics Canada
e-mail: quenne@statcan.ca

Consider a sample of size n denoted by (Subscript[X, 1 ,   ...  ,  ]) (Subscript[X, n])  from an exponential distribution with mean μ and let T = (∑_(i = 1)^n) (Subscript[X, i]) .   The the likelihood function for λ can be written \(TraditionalForm
      \`L(μ) = \(\(μ\^-\)\^n\) e\^\(\(-T\)/μ\)\), the mle of μ is given by \(TraditionalForm\`μ\&^ = T/n\) and the mele of μ is  \(TraditionalForm\`μ\&_ = T/\(\((n - 2)\) . \)\)  The Jeffrey's prior is π(μ) ∝ (μ^(-1)) which produces a Bayes estimate of \(TraditionalForm\`μ\&~ = T/\(\((n - 1)\) . \)\) It is easily seen that the mle is always more efficient than either the mele or Bayes estimator. The situation is summarized in the graph below.

Since T has a standard gamma distribution with shape parameter n and scale parameter μ, the PMC is easily evaluated using the Geary-Rao Theorem (Keating, Mason and Sen, 1993, p.120),

\(TraditionalForm
    \`PMC(a, μ\&^ | μ) = 
      ∫\_0\%b
          \(\( e\^\(-\(x\/μ\)\)\ x\^\(n - 1\)\ 
                μ\^\(-n\)\)\/\(Γ(n)\)\) 
          dx\)

where \(TraditionalForm\`a = μ\&^\) or \(TraditionalForm\`a = μ\&~\) and  b = μ n (n - 2)/(n - 1) or b = 2  μ n (n - 1)/(2  n - 1) according as \(TraditionalForm\`a = μ\&^\) or \(TraditionalForm\`a = μ\&~\). Notice that without loss of generality we may take μ = 1 since \(TraditionalForm
      \`PMC(μ\&_, μ\&^ | μ) = PMC(μ\&_, μ\&^ | 1)\). From the figure below we see that the mele and Bayes estimator do not perform as well as the mle.

Derivations: MLE and MELE

L =  μ^(-n) E^(-T/ μ);

First, the maximum likelihood estimator is derived.

DlogL = D[Log[L],  μ]

{μhat} = μ /. Solve[DlogL  == 0,  μ]

Now the mean likelihood estimator is obtained. Since the integrals are known to coverge we turn off the option GenerateConditions.

SetOptions[Integrate, GenerateConditions -> False];

μbar = 
      Integrate[μ L,  {μ, 0, ∞}]/
          Integrate[ L,  {μ, 0, ∞}] // FullSimplify

Since the mean likelihood estimate shares the same transformation property as the maximum likelihood estimate, we see that the mean likelihood estimate of μ is given by \(TraditionalForm\`μ\&_\  = \ T/\((n - 2)\)\).
Now it is well known and can easily be established using moment generating functions that T has a gamma distribution with shape parameter n and scale parameter μ = (λ^(-1)) .  Using this fact the mean square errors for the maximum likelihood estimate and the mean likelihood estimate may now be derived.

Needs["Statistics`ContinuousDistributions`"];

pdfT [T_]  :=  PDF[GammaDistribution[n,  μ],  T]

msehat  =  
      Integrate[(μ - μhat)^2 pdfT[T], {T, 0, ∞}]

msebar  =  
      Integrate[(μ - μbar)^2 pdfT[T], {T, 0, ∞}]

eff = msehat/msebar  // FullSimplify

Save TeX formula

TeXForm[eff] >> "c:\\p\\math\\1999\\mele\\lifeeff.tex"

eff2 = eff /. n -> 1/m

sereff2 = Series[eff2, {m, 0, 5}]

sereff = sereff2 /. m -> 1/n

Save this result in TeX form

TeXForm[sereff] >> "c:\\p\\math\\1999\\mele\\lifeeff2.tex"

Plot[eff, {n, 3, 50}, PlotRange -> {Automatic, {0. , 1}}, 
      Axes -> False, Frame -> True, FrameLabel -> {"n", "R"}];

Derivations: Bayesian estimator

Fisher information. Divide by n to get large-sample information per observation.

DlogL2 = D[DlogL, μ] // FullSimplify

Iμ = -(DlogL2 /. T -> n μ)/n

μtilde = 
      Integrate[μ L Sqrt[Iμ],  {μ, 0, ∞}]/
          Integrate[ L Sqrt[Iμ],  {μ, 0, ∞}] // 
        FullSimplify

msetilde  =  
      Integrate[(μ - μtilde)^2 pdfT[T], {T, 0, ∞}]

effb = msehat/msetilde  // FullSimplify

<<  Graphics`Legend`

Plot[{eff, effb}, {n, 3, 50}, PlotRange -> {Automatic, {0. , 1}}, 
      Axes -> False, Frame -> True, RotateLabel -> False, 
      FrameLabel -> {"n", "R"}, 
      PlotStyle -> {{}, {Dashing[{0.005, 0.01}]}}, 
      PlotLegend -> {"mele", "Bayes"}, LegendShadow -> None, 
      LegendPosition -> {0.2, -0.25}];

PMC[n_, μ_] := 
      With[{x1 = n μ (n - 2)/(n - 1)}, 
        CDF[GammaDistribution[n, μ], x1]]

PMCb[n_, μ_] := 
      With[{x1 = 2  n μ (n - 1)/(2  n - 1)}, 
        CDF[GammaDistribution[n, μ], x1]]

Plot[{PMC[n, 1], PMCb[n, 1]}, {n, 3, 50}, PlotRange -> All, 
      Axes -> False, Frame -> True, RotateLabel -> False, 
      FrameLabel -> {"n", "PMC"}, AxesOrigin -> {0, 0}, 
      PlotStyle -> {{}, {Dashing[{0.005, 0.01}]}}, 
      PlotLegend -> {"mele", "Bayes"}, LegendShadow -> None, 
      LegendPosition -> {0.2, -0.25}];